Un actualizador que publiqué en octubre de 2024 tenía una condición equivocada: <0 donde debía ir <1. Cuando el INPC baja entre el vencimiento y el pago, una contribución de 100,000.00 se reduce a 99,920.00 en lugar de quedarse en 100,000.00, y ninguna celda marca error. Esta es la versión corregida, con rangos dinámicos para que el libro crezca cada año sin tocar fórmulas. Los datos del papel de trabajo son ilustrativos, no oficiales.
Qué calcula
Parte de una contribución omitida, la actualiza con el factor del artículo 17-A del Código Fiscal de la Federación y calcula los recargos del artículo 21 sobre la contribución ya actualizada. El libro tiene tres hojas: INPC, Recargos y el cálculo.
Las dos matrices
INPC guarda el índice por año (filas) y mes (columnas). La columna de años la genera SECUENCIA, que crece con el número de renglones.
Recargos guarda la tasa mensual por ejercicio con la misma forma. Las capturas de este post son de 2024 y llegan a ese año; el papel de trabajo trae datos hasta 2026.
Rangos dinámicos con DESREF
Una fórmula que lee INPC!$A$9:$M$27 deja de servir el día que agregas 2027. Un nombre definido con DESREF se ajusta solo al número de años y de meses. En Fórmulas → Administrador de nombres → Nuevo se crean cuatro:
INPC = DESREF(INPC!$A$9,0,0,CONTARA(INPC!$A$9:$A$300),CONTARA(INPC!$8:$8))
Recargos = DESREF(Recargos!$B$9,0,0,CONTARA(Recargos!$A$9:$A$300),CONTARA(Recargos!$8:$8)-1)
Recargos_Ejercicio = DESREF(Recargos!$A$9,0,0,CONTARA(Recargos!$A$9:$A$300),1)
Recargos_Periodo = DESREF(Recargos!$B$8,0,0,1,CONTARA(Recargos!$8:$8)-1)
DESREF recibe una celda de partida, cuántas filas y columnas se mueve y el alto y el ancho del rango. El alto sale de contar los años de la columna A y el ancho, de contar los encabezados de la fila 8.
Recargos es la tabla de tasas sin la columna de años ni los encabezados:
Recargos_Ejercicio es solo la columna de años:
Y Recargos_Periodo, solo la fila de meses:
En mi versión de 2024 contaba la columna A completa; cualquier texto arriba de la fila 9 desajustaba el rango. Contar solo A9:A300 lo evita. La prueba está en la hoja Calculo: al escribir 2027 en la primera celda vacía de Recargos, los renglones que ve el nombre pasan de 19 a 20 sin tocar nada.
La actualización y el piso de 1
El factor es el INPC del mes anterior al pago entre el INPC del mes anterior al vencimiento, truncado a cuatro decimales y nunca menor a 1:
=SI(O(C14=0,C15=0),"Falta INPC",MAX(1,TRUNCAR(C14/C15,4)))
En la captura de 2024 las celdas eran otras; la lógica es la misma.
La fórmula original era esta:
=SI.ERROR(SI((G18/G19)<0,0,REDONDEAR((G18/G19)-1,4)),0)
Un cociente de INPC nunca es negativo, así que <0 nunca se cumple y el piso no existía. Además, un INPC faltante se leía como 0: con el del pago en blanco la tasa salía de -100 %, y con el del vencimiento en blanco SI.ERROR la volvía 0, sin avisar. Con datos ilustrativos:
| Caso | Cociente | Con <0 |
Con <1 |
|---|---|---|---|
| Abril pagado en septiembre | 0.99921 | 99,920.00 | 100,000.00 |
| Enero pagado en octubre | 1.00850 | 88,193.63 | 88,193.63 |
| Marzo pagado en agosto | 1.00039 | 215,386.87 | 215,365.34 |
El primer caso es el del piso. El tercero difiere por otra razón: la fórmula original redondeaba el factor y esta hoja lo trunca.
Recargos: meses y tasa
Los meses se cuentan por mes o fracción de mes, como pide el artículo 21:
=(AÑO(C10)-AÑO(C9))*12+MES(C10)-MES(C9)-(DIA(C10)<DIA(C9))+(DIA(C10)<>DIA(C9))
La tasa acumulada suma la tasa de cada mes transcurrido. FECHA recibe la columna de años y la fila de meses, así que arma una matriz de fechas del tamaño de Recargos; las dos comparaciones dejan 1 en los meses del atraso y SUMAPRODUCTO suma sus tasas:
=SUMAPRODUCTO((FECHA(Recargos_Ejercicio,COLUMNA(Recargos_Periodo)-COLUMNA(Recargos!$B$8)+1,1)>=FECHA(AÑO(C9),MES(C9)+1,1))*(FECHA(Recargos_Ejercicio,COLUMNA(Recargos_Periodo)-COLUMNA(Recargos!$B$8)+1,1)<=FECHA(AÑO(C9),MES(C9)+C26,1))*Recargos)/100
(En Excel en inglés: OFFSET, COUNTA, IF, OR, MAX, TRUNC, DATE, COLUMN y SUMPRODUCT.)
El caso de la captura original, de mayo de 2016 a octubre de 2024, da 101 meses y 142.01 %, igual que en 2024.
El método original usaba el día 17 fijo para el pago, así que un pago el 20 contaba un mes menos. En el papel de trabajo, cambiar el día de pago de 17 a 20 (celda C10) sube los meses de 5 a 6. El control compara los meses del artículo 21 con los meses para los que la tabla Recargos tiene tasa; si falta un ejercicio dice «Falta la tasa de algún mes».
Verifica antes de usarlo
Verifica lo vigente: contrasta los artículos 17-A y 21 del Código Fiscal de la Federación con el texto publicado en el DOF. El INPC se toma del INEGI y las tasas, de la Ley de Ingresos de la Federación de cada ejercicio; las de 2025 y 2026 (1.47 % y 2.07 % mensual de mora) las cito en Recargos y actualización en Excel con LET. El archivo no trae la tasa de 2027. Verifica cada dato antes de usarlo con un cliente.
Límites
- Los INPC del archivo son ilustrativos. Captura los oficiales antes de calcular un adeudo real.
- Cada mes de atraso usa la tasa del mes calendario en que termina. Es la convención de esta hoja; confirma con tu despacho cómo tratas un atraso que cruza de un año a otro.
- El truncado a cuatro decimales es criterio de esta hoja. La fórmula original redondeaba.
DESREFes volátil: se recalcula con cada cambio del libro. Con INPC y Recargos en Tablas de Excel (CTRL + T) ya no hace falta; así lo hago en Recargos y actualización en Excel con LET.- No incluye multas, pagos parciales ni devoluciones. Para el factor con una matriz completa, mira Matriz de factores de actualización en Excel; la parte 2 de esta serie plantea otro método para los recargos.
Papel de trabajo
Descarga el papel de trabajo del actualizador, con INPC ilustrativo, sin registro y sin correo. Trae siete casos y nueve pruebas con el resultado esperado.
Si quieres que revisemos cómo actualiza tu despacho los adeudos, platiquemos.