Una tarifa de ISR copiada de una página, de un PDF o del archivo del año pasado puede traer un dígito invertido en la cuota fija de un renglón. Cada sueldo que cae en ese renglón sale con otro impuesto, y Excel no marca nada: una cuota fija mal copiada es un número tan válido como la correcta.

Antes de usar una tarifa con un cliente la verifico con una prueba que no depende de la fuente: la continuidad. Esta es la pieza 2 de 8 de la serie «LET en el despacho». La pieza 1 clasificó una cartera con LET; esta calcula el ISR por tarifa con LET.

Infografía: una cuota fija con un dígito invertido cambia 9.00 el ISR de un sueldo de 20,000.00 y la prueba de saltos lo detecta / Infographic: a swapped digit in a fixed fee changes the ISR on a 20,000.00 salary by 9.00 and the jump check catches it

Qué cambia un dígito

La tarifa mensual del artículo 96 tiene 11 renglones. En el renglón 6 la cuota fija correcta es 1,856.84. Si se copia como 1,865.84, con el 5 y el 6 invertidos, un sueldo gravado de 20,000.00 da 2,392.65 de ISR en lugar de 2,383.65: 9.00 de más por sueldo y por mes.

Hoja Auditoría: ISR de 20,000.00 con la tarifa correcta 2,383.65 y con el error 2,392.65, diferencia de 9.00 / Auditoría sheet: ISR on 20,000.00 is 2,383.65 with the correct table and 2,392.65 with the error, a 9.00 difference

Nada falla en la hoja: la fórmula devuelve un importe razonable. El error solo se ve al compararlo contra una referencia.

Verificar la tarifa: el ISR no debe dar saltos

Una tarifa por renglones está hecha para que el impuesto crezca sin saltos: el ISR en el límite superior de un renglón debe ser igual a la cuota fija del renglón siguiente. Con la tarifa mensual 2026 bien copiada, la diferencia entre ambos es de uno o dos centavos, por el redondeo.

La verificación son cuatro columnas junto a la tarifa (B es el límite inferior, C el superior, D la cuota fija y E la tasa):

F12: =D12+(C12-B12)*E12            ISR en el límite superior
G12: =D13                          cuota fija siguiente
H12: =REDONDEAR(F12-G12,2)         salto
I12: =SI(ABS(H12)<=0.05,"OK","REVISAR")

La tolerancia es de 0.05: lo normal es 0.00 o 0.01.

Hoja Auditoría: los saltos entre renglones son 0.00, 0.01 y -0.01, todos OK, y el contador de REVISAR marca 0 / Auditoría sheet: jumps between rows are 0.00, 0.01 and -0.01, all OK, and the REVISAR counter shows 0

Con la cuota fija del renglón 6 en 1,865.84 aparecen dos saltos seguidos: −8.99 en el corte del renglón 5 al 6 y +8.99 en el del 6 al 7. Un salto negativo seguido de uno positivo de la misma magnitud señala el renglón de en medio. Cuando lo que falla es una tasa o un límite, se marca un solo renglón.

Hoja Auditoría, celda H33 activa. La barra muestra =REDONDEAR(F33-G33,2). Rango visible: A27:I39. -8.99 en H32 y 8.99 en H33, «REVISAR» en I32 e I33, 1,865.84 en D33 e 2 en I39.

Calcular el ISR con LET

(En Excel en inglés: XMATCH, INDEX, ROUND y VLOOKUP.)

=LET(ing,tblCasos[Ingreso gravado],fila,COINCIDIRX(ing,tblTarifa[Límite inferior],-1),REDONDEAR((ing-INDICE(tblTarifa[Límite inferior],fila))*INDICE(tblTarifa[Tasa],fila)+INDICE(tblTarifa[Cuota fija],fila),2))

fila guarda la posición del renglón donde cae el ingreso. COINCIDIRX con −1 devuelve el renglón exacto o el menor inmediato, así que 844.60 cae en el renglón 2 y 844.59 en el 1. INDICE usa fila tres veces: límite inferior, tasa y cuota fija. Es una sola celda y se desborda por toda la columna.

Para reconstruirlo:

  1. Convierte la tarifa en tabla con CTRL + T y llámala tblTarifa, con las columnas Límite inferior, Límite superior, Cuota fija y Tasa.
  2. Convierte los ingresos en otra tabla, tblCasos, con la columna Ingreso gravado.
  3. Escribe la fórmula una sola vez en la primera celda de resultados.

El método de siempre hace tres BUSCARV, tres búsquedas por cada ingreso:

=REDONDEAR(BUSCARV(B12,Tarifa!$A$9:$D$19,3,VERDADERO)+(B12-BUSCARV(B12,Tarifa!$A$9:$D$19,1,VERDADERO))*BUSCARV(B12,Tarifa!$A$9:$D$19,4,VERDADERO),2)

Hoja Calculo: ISR con LET y con tres BUSCARV para los mismos ingresos, con 0.00 de diferencia absoluta / Calculo sheet: ISR with LET and with three VLOOKUPs for the same incomes, with 0.00 absolute difference

El papel de trabajo prueba 24 ingresos: el tope y el piso de cada renglón, un importe a cada lado de cada corte, y cuatro sueldos de práctica. La suma de diferencias absolutas entre los dos métodos es 0.00.

Limitaciones

  • La tarifa del papel de trabajo es la mensual 2026 del Anexo 8 de la RMF (DOF 28-12-2025), transcrita de fuentes que coinciden entre sí. Compárala contra el PDF oficial del SAT antes de usarla con un cliente.
  • La verificación confirma que la tarifa es coherente, no que sea la vigente.
  • El último renglón no tiene siguiente: su tasa y su límite inferior no se verifican.
  • El cálculo es el ISR antes de subsidio para el empleo; no es la retención final de un sueldo bajo.
  • Requiere Excel 365 (LET y COINCIDIRX).

Conclusión

Una tarifa copiada se revisa antes de usarla, y la continuidad es la revisión que no depende de la fuente. LET deja el cálculo del ISR en una celda legible.

El papel de trabajo con las dos tarifas, los 24 casos frontera y las fórmulas está en aquí

¿Necesitas revisar el cálculo del ISR de la nómina de tu despacho? Escríbeme.